Вставка таблиц в word vba

Your code lacks precision. You should try to build it more methodical, like, first create an instance of the Word application. Then let that application create a document. Then place a table into that document. Then look for a cell in that table. And add text to that cell only now.

In comparison, you create the Word application, don’t create any document, add a table to the document which doesn’t exist, and — presumably in desperation — then try to add text to the application. The Word application doesn’t have a selection (your wordObj.Selection), only a document does.

The following code does what you want. I have written it for your ease of understanding. Don’t think it’s «baby language» because it isn’t. It just doesn’t cut corners. You can learn how to cut corners after you are more proficient — if you still want to. Bear in mind, the more corners you cut the less stable your code will be.

Sub WriteToWordTable()

    ' declarations for the Excel application:
    Dim Ws As Worksheet

    ' declarations for the Word application:
    Dim wordObj As Word.Application
    Dim outFile As Word.Document
    Dim outTable As Word.Table
    Dim wdRng As Word.Range

    Set Ws = ActiveSheet
    Ws.Cells(2, "A").value = "Test1"

    On Error Resume Next
    Set wordObj = GetObject(, "Word.Application")

    If wordObj Is Nothing Then
        Set wordObj = CreateObject("Word.Application")
    End If

    Set outFile = wordObj.Documents.Add
    With outFile
        Set wdRng = .Range(0, 0)
        Set outTable = .Tables.Add(Range:=wdRng, _
                                   NumRows:=1, NumColumns:=3)
    End With

    With outTable
        .Cell(1, 1).Range.Text = Ws.Cells(2, "A").value
        .Rows.Add
        .Cell(2, 1).Range.Text = "Test2"
    End With

    With wordObj.ActiveWindow
        .Visible = True
        .Activate
    End With

'    outFile.Close
'    wordObj.Quit
End Sub

BTW, you don’t need to make the Word document visible at any time. You could quietly close the Word application and continue working in Excel. However, for that purpose you would need to save the outFile before closing it and then shutting down Word.

Visual Basic для приложений (VBA) — очень мощный инструмент, который можно использовать для автоматизации большой работы между несколькими приложениями Microsoft Office. Одним из распространенных действий, которые вы можете автоматизировать с помощью VBA, является вставка таблицы Excel в документ Word.

Есть два способа сделать это. Первый — это автоматическое копирование и вставка существующего диапазона из Excel в новую таблицу в документе Word. Второй — выполнение расчетов в Excel, создание новой таблицы в Word и запись результатов в таблицу.

Вы можете попытаться записать макрос, чтобы сделать это, но макросы позволят вам только автоматизировать задачи внутри Word. В этой статье вы узнаете, как писать код VBA для автоматизации этих действий между Excel и Word.

В обоих примерах мы начнем с образца электронной таблицы Excel. Этот образец представляет собой список заказов на покупку различных продуктов.

Допустим, вы хотите скопировать и вставить весь диапазон ячеек на этом листе в документ Word. Для этого вам нужно написать функцию VBA, которая будет запускаться при нажатии кнопки «Копировать в слово».

Выбрать разработчик из меню и выберите Вставить из группы управления на ленте. В раскрывающемся списке выберите элемент управления «Кнопка» в разделе «Элементы управления ActiveX».

Затем нарисуйте командную кнопку на правой стороне листа. Вы можете изменить заголовок на «Копировать в Word», щелкнув правой кнопкой мыши по кнопке и выбрав свойства, Измените текст заголовка, и вы можете использовать шрифт для обновления размера и стиля шрифта.

Запись: Если вы не видите разработчик в меню Excel, затем добавьте его. Выбрать файл, Опции, Настроить лентуи выберите Все команды из выпадающего списка слева. Тогда двигайся разработчик от левой панели вправо и выберите OK, чтобы закончить.

Напишите копию и вставьте код VBA

Теперь вы готовы начать писать код VBA. Чтобы начать, дважды щелкните новый Копировать в Word кнопка, чтобы открыть окно редактора кода.

Вы должны увидеть подпрограмму с именем Commandbutton1_Click (), как показано ниже.

Вы хотите скопировать каждый раздел кода ниже. Прежде чем приступить к написанию кода, для управления Word на вашем компьютере с помощью VBA необходимо включить справочную библиотеку Microsoft Word.

В редакторе кода выберите инструменты из меню и выберите Ссылки, В списке доступных ссылок прокрутите вниз и включите Библиотека объектов Microsoft Word 16.0,

Выберите OK, и вы готовы начать кодирование. Мы рассмотрим каждый раздел кода за раз, чтобы вы поняли, что делает этот код и почему.

Во-первых, вам нужно создать переменные и объекты, которые будут содержать диапазон и позволять вам управлять приложением Word.

Dim tblRange As Excel.Range
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Dim WordTable As Word.Table

Следующая строка кода выбирает определенный диапазон ячеек и сохраняет его в объекте диапазона Excel в VBA.

Set tblRange = ThisWorkbook.Worksheets("Sheet1").Range("A2:G44")


Затем вы хотите проверить, открыто ли приложение Word на компьютере. Для этого вы можете ссылаться на приложение Word, используя специальную ссылку «класс» с командой VBA GetObject. Если Word еще не открыт, то следующая строка запустит его с помощью функции CreateObject. Строка «On Error Resume Next» предотвращает любую ошибку первой функции GetObject (если Word еще не открыт) останавливать выполнение следующей строки в программе.

On Error Resume Next
Set WordApp = GetObject(class:="Word.Application")
If WordApp Is Nothing Then Set WordApp = CreateObject(class:="Word.Application")

Теперь, когда приложение Word запущено, вы хотите сделать его видимым для пользователя и активировать его для использования.

WordApp.Visible = True
WordApp.Activate


Далее вы хотите создать новый документ в приложении Word.

Set WordDoc = WordApp.Documents.Add

Наконец, вы скопируете и вставите диапазон ячеек в новую таблицу в документе Word.

tblRange.Copy
WordDoc.Paragraphs(1).Range.PasteExcelTable _
LinkedToExcel:=False, _
WordFormatting:=False, _
RTF:=False


Переключатели в вышеупомянутой функции вставят несвязанную таблицу, используя исходное форматирование Excel (не форматирование Word) и не используя расширенный текстовый формат.

Наконец, для работы с диапазонами Excel, которые шире, чем документ, вам нужно автоматически установить новую таблицу, чтобы она соответствовала полям вашего нового документа Word.

Set WordTable = WordDoc.Tables(1)
WordTable.AutoFitBehavior (wdAutoFitWindow)


И теперь вы сделали! Сохраните файл как файл Excel с поддержкой макросов (расширение .xlsm). Закройте редактор, снова сохраните исходный файл Excel, а затем нажмите командную кнопку, чтобы увидеть код в действии!

Записать результаты Excel в таблицу Word с помощью VBA

В следующем разделе вы напишете код VBA, который выполняет вычисления значений в Excel и записывает их в таблицу в Word.

Для этого примера мы возьмем данные на 10 строк, вычислим и запишем результаты в таблицу в документе Word. Кроме того, исходная таблица будет содержать четыре столбца, а код VBA извлечет первые десять строк данных из этого диапазона.

Как и в последнем разделе, мы рассмотрим каждый раздел за раз, чтобы вы понимали, что делает этот код и почему.

Сначала создайте переменные и объекты, которые будут содержать данные и позволят вам писать в приложение Word.

Dim tblRange As Excel.Range
Dim WrdRange As Word.Range
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Dim WordTable As Word.Table
Dim intRows
Dim intColumns
Dim strDate As String
Dim strItem As String
Dim intUnits As Variant
Dim intCost As Variant
Dim intTotal As Variant

Затем установите общее количество столбцов и строк, которые вы хотите прочитать из диапазона Excel.


intNoOfRows = 10
intNoOfColumns = 5


Повторите тот же код, что и в последнем разделе, который откроет Word, если он еще не открыт.

On Error Resume Next
Set WordApp = GetObject(class:="Word.Application")
If WordApp Is Nothing Then Set WordApp = CreateObject(class:="Word.Application")
WordApp.Visible = True
WordApp.Activate
Set WordDoc = WordApp.Documents.Add


Следующие четыре строки создают таблицу внутри вновь открытого документа Word.

Set WrdRange = WordDoc.Range(0, 0)
WordDoc.Tables.Add WrdRange, intNoOfRows, intNoOfColumns
Set WordTable = WordDoc.Tables(1)
WordTable.Borders.Enable = True


Наконец, следующий цикл выполнит эти действия:

1. Для каждой строки поместите дату заказа, позицию, единицы и стоимость в переменные
2. Рассчитайте стоимость за единицу времени (общую продажу) и сохраните ее в переменной
3. Для каждого столбца запишите значения в таблицу Word, включая рассчитанный общий объем продаж в последней ячейке.
4. Перейдите к следующему ряду и повторите процедуру выше

Вот как выглядит этот код:

For i = 1 To intNoOfRows
For j = 1 To intNoOfColumns
If j = 1 Then
strDate = tblRange.Cells(i + 1, j).Value
strItem = tblRange.Cells(i + 1, j + 1).Value
intUnits = Val(tblRange.Cells(i + 1, j + 2).Value)
intCost = Val(tblRange.Cells(i + 1, j + 3).Value)
intTotal = intUnits * intCost
End If
Select Case j
Case Is = 1
WordTable.Cell(i, j).Range.Text = strDate
Case Is = 2
WordTable.Cell(i, j).Range.Text = strItem
Case Is = 3
WordTable.Cell(i, j).Range.Text = intUnits
Case Is = 4
WordTable.Cell(i, j).Range.Text = intCost
Case Is = 5
WordTable.Cell(i, j).Range.Text = intTotal
Case Else
End Select
Next
Next


Функция «Ячейки» в первой части извлекает значения ячеек из Excel. Ячейки (x, y) означают, что он извлекает значение ячейки в строке x и столбце y.
Функция «Ячейка» в последней части записывает данные в ячейки таблицы Word, используя те же назначения строк и столбцов.

После сохранения и запуска этого кода VBA вы увидите результаты в только что созданном документе Word.

Как видите, не так сложно создать полезную автоматизацию между Excel и Word. Это просто вопрос понимания того, как работают различные «объекты», которые могут создавать и контролировать приложения Excel и Word на вашем компьютере.