Как заменить ошибку в excel на 0

Хитрости »

7 Октябрь 2015              49613 просмотров

Случаются ситуации, когда в рабочей книге на листах создано много формул, выполняющих различные задачи. При этом формулы созданы когда-то давно, возможно даже на вами. И формулы возвращают ошибки. Например #ДЕЛ/0!(#DIV/0!). Эта ошибка возникает, если внутри формулы происходит деление на ноль: =A1/B1, где в B1 ноль или пусто. Но могут быть и другие ошибки(#Н/Д, #ЗНАЧ! и т.д.). Можно изменить формулу, добавив проверку на ошибку:
=ЕСЛИ(ЕОШ(A1/B1);0; A1/B1)
=IF(ISERR(A1/B1),0, A1/B1)
аргументы:
=ЕСЛИ(ЕОШ(1 аргумент);2 аргумент; 1 аргумент)
Эти формулы будут работать в любой версии Excel. Правда, функция ЕОШ не обработает ошибку #Н/Д(#N/A). Чтобы так же обработать и #Н/Д необходимо использовать функцию ЕОШИБКА:
=ЕСЛИ(ЕОШИБКА(A1/B1);0; A1/B1)
=IF(ISERROR(A1/B1),0, A1/B1)
Однако далее по тексту я буду применять ЕОШ(т.к. она короче) и к тому же не всегда надо «не видеть» ошибки #Н/Д.
Но для версий Excel 2007 и выше можно применить чуть более оптимизированную функцию ЕСЛИОШИБКА(IFERROR):
=ЕСЛИОШИБКА(A1/B1;0)
=IFERROR(A1/B1,0)
аргументы:
=ЕСЛИОШИБКА(1 аргумент; 2 аргумент)

1 аргумент: выражение для вычисления
2 аргумент: значение или выражение, которое необходимо вернуть в ячейку в случае ошибки в первом аргументе.

Почему ЕСЛИОШИБКА лучше и я называю её более оптимизированной?

Разберем первую формулу подробнее:

=ЕСЛИ(ЕОШ(A1/B1);0; A1/B1)

Если вычислить пошагово, то увидим, что сначала происходит вычисление выражения

A1

/

B1

(т.е. деление). И если его результат ошибка – то ЕОШ вернет

ИСТИНА(TRUE)

, которое будет передано в

ЕСЛИ(IF)

. И тогда функцией

ЕСЛИ(IF)

будет возвращено значение из второго аргумента 0.
Но если результат не является ошибочным и

ЕОШ(ISERR)

возвращает

ЛОЖЬ(FALSE)

– то функция заново будет вычислять уже вычисленное ранее выражение:

A1

/

B1

С приведенной формулой это особой роли не играет. Но если применяется формула вроде ВПР (VLOOKUP) с просмотром на несколько тысяч строк – то вычисление два раза может значительно увеличить время пересчета формул.
Функция же

ЕСЛИОШИБКА(IFERROR)

один раз вычисляет выражение, запоминает его результат и если он ошибочен возвращает записанное вторым аргументом. Если же ошибки нет, то возвращает запомненный результат вычисления выражения из первого аргумента. Т.е. вычисление по факту происходит один раз, что практически не будет влиять на скорость общего пересчета формул.
Поэтому если у вас Excel 2007 и выше и файл не будет использоваться в более ранних версиях – то имеет смысл использовать именно

ЕСЛИОШИБКА(IFERROR)

.

Для чего формулы с ошибками вообще исправлять? Обычно делается для более эстетичного отображения данных в отчетах, особенно если отчеты потом руководству отправляют.

Итак, есть на листе такие формулы, ошибки которых надо обработать. Если подобных формул для исправления одна-две(да даже 10-15) – то проблем почти нет заменить вручную. Но если таких формул несколько десятков, а то и сотен – проблема приобретает почти вселенские масштабы :-). Однако процесс можно упростить через написание относительно простого кода Visual Basic for Application.

Для всех версий Excel:

Sub IfIsErrNull()
    Const sToReturnVal As String = "0"
    'если необходимо вместо нуля возвращать пусто
    'Const sToReturnVal As String = """"""
    Dim rr As Range, rc As Range
    Dim s As String, ss As String
    On Error Resume Next
    Set rr = Intersect(Selection, ActiveSheet.UsedRange)
    If rr Is Nothing Then
        MsgBox "Выделенный диапазон не содержит данных", vbInformation, "www.excel-vba.ru"
        Exit Sub
    End If
 
    For Each rc In rr
        If rc.HasFormula Then
            s = rc.Formula
            s = Mid(s, 2)
            ss = "=" & "IF(ISERR(" & s & ")," & sToReturnVal & "," & s & ")"
            If Left(s, 9) <> "IF(ISERR(" Then
                If rc.HasArray Then
                    rc.FormulaArray = ss
                Else
                    rc.Formula = ss
                End If
                If Err.Number Then
                    ss = rc.Address
                    rc.Select
                    Exit For
                End If
            End If
        End If
    Next rc
    If Err.Number Then
        MsgBox "Невозможно преобразовать формулу в ячейке: " & ss & vbNewLine & _
                Err.Description, vbInformation, "www.excel-vba.ru"
    Else
        MsgBox "Формулы обработаны", vbInformation, "www.excel-vba.ru"
    End If
End Sub

Для версий 2007 и выше

Sub IfErrorNull()
    Const sToReturnVal As String = "0"
    'если необходимо вместо нуля возвращать пусто
    'Const sToReturnVal As String = """"""
    Dim rr As Range, rc As Range
    Dim s As String, ss As String
    On Error Resume Next
    Set rr = Intersect(Selection, ActiveSheet.UsedRange)
    If rr Is Nothing Then
        MsgBox "Выделенный диапазон не содержит данных", vbInformation, "www.excel-vba.ru"
        Exit Sub
    End If
 
    For Each rc In rr
        If rc.HasFormula Then
            s = rc.Formula
            s = Mid(s, 2)
            ss = "=" & "IFERROR(" & s & "," & sToReturnVal & ")"
            If Left(s, 8) <> "IFERROR(" Then
                If rc.HasArray Then
                    rc.FormulaArray = ss
                Else
                    rc.Formula = ss
                End If
                If Err.Number Then
                    ss = rc.Address
                    rc.Select
                    Exit For
                End If
            End If
        End If
    Next rc
 
    If Err.Number Then
        MsgBox "Невозможно преобразовать формулу в ячейке: " & ss & vbNewLine & _
                Err.Description, vbInformation, "www.excel-vba.ru"
    Else
        MsgBox "Формулы обработаны", vbInformation, "www.excel-vba.ru"
    End If
End Sub

Как это работает
Если не знакомы с макросами, то для начала лучше прочитать как их создавать и вызывать: Что такое макрос и где его искать?, т.к. может случиться так, что все сделаете правильно, но забудете макросы разрешить и ничего не заработает.

Копируете приведенный код, переходите в редактор VBA(Alt+F11), создаете стандартный модуль(Insert —Module) и просто вставляете в него этот код. Переходите в нужную книгу Excel и выделяете все ячейки, формулы в которых необходимо преобразовать таким образом, чтобы в случае ошибки они возвращали ноль. Жмете Alt+F8, выбираете код IfIsErrNull(или IfErrorNull, в зависимости от того, какой именно скопировали) и жмете Выполнить.
Ко всем формулам в выделенных ячейках будет добавлена функция обработки ошибки. Приведенные коды учитывают так же:
-если в формуле уже применена функция ЕСЛИОШИБКА или ЕСЛИ(ЕОШ, то такая формула не обрабатывается;
-код корректно обработает так же функции массива;
-выделять можно несмежные ячейки(через Ctrl).
В чем недостаток: сложные и длинные формулы массива могут вызвать ошибку кода, в связи с особенностью данных формул и их обработкой из VBA. В таком случае код напишет о невозможности продолжить работу и выделит проблемную ячейку. Поэтому настоятельно рекомендую производить замены на копиях файлов.
Если значение ошибки надо заменить на пусто, а не на ноль, то надо строку

Const sToReturnVal As String = "0"

Удалить, а перед строкой

'Const sToReturnVal As String = """"""

Удалить апостроф (‘)

Так же можно данный код вызывать нажатием кнопки(Как создать кнопку для вызова макроса на листе) или поместить в надстройку(Как создать свою надстройку?), чтобы можно было вызывать из любого файла.

И небольшое дополнение: старайтесь применять код вдумчиво. Не всегда возврат ошибки мешает. Например, при использовании ВПР иногда полезно видеть какие значения не были найдены.
Так же хочу отметить, что применять надо к реально работающим формулам. Потому как если формула возвращает #ИМЯ!(#NAME!), то это означает, что в формуле неверно записан какой-то аргумент и это ошибка записи формулы, а не ошибка результата вычисления. Такие формулы лучше проанализировать и найти ошибку, чтобы избежать логических ошибок расчетов на листе.

Статья помогла? Поделись ссылкой с друзьями!

    Видеоуроки

Поиск по меткам



Access
apple watch
Multex
Power Query и Power BI
VBA управление кодами
Бесплатные надстройки
Дата и время
Записки
ИП
Надстройки
Печать
Политика Конфиденциальности
Почта
Программы
Работа с приложениями
Разработка приложений
Росстат
Тренинги и вебинары
Финансовые
Форматирование
Функции Excel
акции MulTEx
ссылки
статистика

Вы можете часто встречать некоторые значения ошибок в книгах Excel, такие как #DIV/0, #VALUE!, #REF, #N/A, #NUM!, #NAME?, #NULL. И здесь мы покажем вам несколько полезных методов для поиска и замены этих # ошибок формулы на 0 (ноль), пробел или любую текстовую строку в Microsoft Excel. Возьмем приведенную ниже таблицу в качестве примера. Давайте прочитаем, чтобы узнать, как искать и заменять значения ошибок в таблице:

Замените # ошибок в формулах на 0, любые конкретные значения или пустые ячейки на ЕСЛИОШИБКА

Microsoft Excel имеет встроенную функцию IFERROR, что позволяет легко преобразовывать любые виды значений ошибок в любые значения по вашему желанию.
Как показано в примере ниже, просто введите =ЕСЛИОШИБКА(значение, значение_если_ошибка) в пустой ячейке, и вы получите ценностное себя, если это не ошибка, или значение_если_ошибка if ценностное это ошибка.

В приведенной выше таблице видно, что значение ошибки #Н/Д было преобразовано в пустую ячейку, число и указанную текстовую строку соответственно. Вы можете изменить значение_если_ошибка к любым значениям, которые вам нужны, как показано в примере ниже:

Примечание: В формуле =ЕСЛИОШИБКА(значение, значение_если_ошибка), ценностное может быть представлен в виде формулы, выражения, значения или ссылки на ячейку. А также значение_если_ошибка может быть пустой строкой, текстовым сообщением, числовым значением или другой формулой или расчетом. Когда вы предоставляете текстовое сообщение как значение_если_ошибка, не забудьте заключить его в двойные кавычки («»).

Замените # ошибок в формулах конкретными числами с помощью ERROR.TYPE.

Обычно мы можем использовать Microsoft Excel ERROR.TYPE функция для возврата числа, соответствующего определенному значению ошибки.
В нашем примере ниже, используя функцию ERROR.TYPE в пустой ячейке, вы получите числовые коды для определенных значений ошибок, так что разные # ошибки формулы будут преобразованы в разные числа:

Конечно, вы можете перетащить маркер заливки чтобы преобразовать другие ошибки формулы в числа по диапазонам. Однако этих цифр слишком много, чтобы их можно было запомнить и применить.

Найдите и замените # ошибки формулы на 0, любые конкретные значения или пустые ячейки с помощью команды «Перейти к».

Таким образом можно легко преобразовать все ошибки формул # в выделенном фрагменте с 0, пустым или любыми другими значениями с помощью Microsoft Excel. Перейти к команда.

Шаг 1: Выберите диапазон, с которым вы будете работать.

Шаг 2: Нажмите F5 , чтобы открыть Перейти к диалоговое окно.

Шаг 3: Нажмите Особый кнопку, и он открывает Перейти к специальному диалоговое окно.

Шаг 4: В разделе Перейти к специальному диалоговое окно, только отметьте Формула вариант и ошибки вариант, см. снимок экрана:

Шаг 5: И затем щелкните OK, были выбраны все # ошибки формулы, см. снимок экрана:

Шаг 6: Теперь просто введите 0 или любое другое значение, необходимое для замены ошибок, и нажмите Ctrl + Enter ключи. Тогда вы получите, что все выбранные ячейки ошибок заполнены 0.

Конечно, вы можете удалить все ячейки с ошибками, нажав клавишу Delete, оставив пустые ячейки.

Найдите и замените # ошибок формулы на 0, любые конкретные значения или пустые ячейки на Kutools for Excel

Если у вас есть Kutools for Excel установлен, его Мастер условий ошибки Инструмент упростит вашу работу, заменив все виды ошибок формул на 0, пустые ячейки или любые пользовательские сообщения.

1: Выберите диапазон со значениями ошибок, которые вы хотите заменить на ноль, пробел или текст, как вам нужно, затем cоблизывание Кутулс > Больше > Мастер условий ошибки. Смотрите скриншот:

2. В разделе Мастер условий ошибки диалоговое окно, сделайте следующее:

И тогда вы можете увидеть, что все значения ошибок в выбранном диапазоне заменяются пробелами, нулями или определенным текстом, как вы сразу указали выше. Смотрите скриншоты:

Замените все значения ошибок пустыми

Замените все значения ошибок на ноль

Замените все значения ошибок определенным текстом

  Если вы хотите получить бесплатную пробную версию (30-день) этой утилиты, пожалуйста, нажмите, чтобы загрузить это, а затем перейдите к применению операции в соответствии с указанными выше шагами.

Найдите и замените # ошибок в формуле на 0 или пробел на Kutools for Excel

Связанная статья:

• Как изменить # DIV / 0! ошибка читабельному сообщению в excel?